Descripción
Este programa agrupa en una única ejecución las principales tareas estándar de invalidación y regeneración de cachés utilizadas en entornos Fiori. Resulta especialmente útil después de actividades técnicas que puedan dejar información inconsistente en memoria o índices obsoletos, tales como copias de mandante, refreshes de sistemas, copias homogéneas o heterogéneas, importación masiva de órdenes de transporte, actualizaciones de componentes SAP_UI o SAP_GWFND, así como despliegues o actualizaciones de aplicaciones SAPUI5/Fiori.
El objetivo es garantizar que los metadatos OData, los índices de aplicaciones, las definiciones del Launchpad y el contenido almacenado en caché se regeneren correctamente, evitando incidencias habituales como aplicaciones Fiori que no aparecen en el Launchpad, servicios OData que siguen mostrando metadatos antiguos, tiles que no se cargan correctamente o inconsistencias posteriores a una copia de sistema o de mandante.
Todos los programas estándar se ejecutan en modo silencioso (background mode), sin mostrar sus pantallas de selección ni sus listas de salida originales. La ejecución se realiza de forma secuencial mediante SUBMIT ... AND RETURN, capturando internamente el resultado de cada proceso.
Para cada paso ejecutado se registra la siguiente información:
- Programa ejecutado.
- Descripción funcional.
- Hora de inicio.
- Hora de finalización.
- Duración de la ejecución.
- Estado final (Correcto/Error).
- Mensajes y salida capturada.
Al finalizar se presenta una lista resumen consolidada con todas las operaciones realizadas y el resultado obtenido en cada una de ellas.
Secuencia de ejecución
- /IWBEP/R_MGW_MED_CACHE_CLEANUP - (Transacción /IWBEP/CACHE_CLEANUP'''): Elimina la caché de metadatos del framework SAP Gateway Backend (/IWBEP). Se ejecuta para todos los servicios registrados con el fin de obligar a la regeneración de los metadatos OData almacenados.
- /IWFND/R_MED_CACHE_CLEANUP - (Transacción /IWFND/CACHE_CLEANUP) : Limpia la caché de metadatos del Gateway Hub (/IWFND), eliminando información almacenada de los servicios OData consumidos por las aplicaciones SAP Fiori.
- /UI5/APP_INDEX_CALCULATE: Recalcula el índice de aplicaciones SAPUI5 para todos los repositorios disponibles. La ejecución se realiza en modo "objetos caducados", regenerando únicamente aquellas entradas que requieren actualización y reduciendo así el tiempo total del proceso.
- /UI2/INVALIDATE_GLOBAL_CACHES: Invalida las cachés globales de SAP Fiori Launchpad compartidas por todos los usuarios del sistema. Estas cachés se reconstruyen automáticamente bajo demanda durante los siguientes accesos.
- /UI2/DELETE_CACHE_AFTER_IMP: Elimina los contenidos de caché asociados a componentes de Launchpad y SAP_UI que puedan haber quedado obsoletos tras una importación de transportes o una copia de sistema. La ejecución se realiza para todos los mandantes existentes.
- . /UI2/INVALIDATE_CLIENT_CACHES: Invalida las cachés específicas de cada mandante y usuario, garantizando que catálogos, grupos, espacios, páginas, roles y demás configuraciones del Launchpad se vuelvan a cargar desde la información actualizada del sistema.
Una vez completada la ejecución de todos los pasos, se recomienda que los usuarios cierren las sesiones activas del navegador y vuelvan a iniciar sesión en SAP Fiori para asegurar que utilizan exclusivamente la información regenerada y evitar posibles inconsistencias derivadas de datos cacheados localmente.
- REPORT zini_limpieza_fiori LINE-SIZE 180 NO STANDARD PAGE HEADING.
- *----------------------------------------------------------------------*
- * Constantes
- *----------------------------------------------------------------------*
- CONSTANTS:
- gc_prog_bep TYPE progname VALUE '/IWBEP/R_MGW_MED_CACHE_CLEANUP',
- gc_prog_fnd TYPE progname VALUE '/IWFND/R_MED_CACHE_CLEANUP',
- gc_prog_ui5 TYPE progname VALUE '/UI5/APP_INDEX_CALCULATE',
- gc_prog_global TYPE progname VALUE '/UI2/INVALIDATE_GLOBAL_CACHES',
- gc_prog_imp TYPE progname VALUE '/UI2/DELETE_CACHE_AFTER_IMP',
- gc_prog_client TYPE progname VALUE '/UI2/INVALIDATE_CLIENT_CACHES',
- gc_memid_glob TYPE char40 VALUE '/UI2/INVALIDATE_GLOBAL_CACHES'.
- *----------------------------------------------------------------------*
- * Pantalla de selección
- *----------------------------------------------------------------------*
- SELECTION-SCREEN BEGIN OF BLOCK b01 WITH FRAME TITLE gv_tit1.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_bep AS CHECKBOX DEFAULT abap_true.
- SELECTION-SCREEN COMMENT 3(75) gv_tbep FOR FIELD p_bep.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_fnd AS CHECKBOX DEFAULT abap_true.
- SELECTION-SCREEN COMMENT 3(75) gv_tfnd FOR FIELD p_fnd.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_ui5 AS CHECKBOX DEFAULT abap_false.
- SELECTION-SCREEN COMMENT 3(75) gv_tui5 FOR FIELD p_ui5.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN END OF BLOCK b01.
- SELECTION-SCREEN BEGIN OF BLOCK b02 WITH FRAME TITLE gv_tit2.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_global AS CHECKBOX DEFAULT abap_true.
- SELECTION-SCREEN COMMENT 3(75) gv_tglo FOR FIELD p_global.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_imp AS CHECKBOX DEFAULT abap_true.
- SELECTION-SCREEN COMMENT 3(75) gv_timp FOR FIELD p_imp.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN BEGIN OF LINE.
- PARAMETERS p_client AS CHECKBOX DEFAULT abap_true.
- SELECTION-SCREEN COMMENT 3(75) gv_tcli FOR FIELD p_client.
- SELECTION-SCREEN END OF LINE.
- SELECTION-SCREEN END OF BLOCK b02.
- *----------------------------------------------------------------------*
- * Clase local: limpiador de cachés
- *----------------------------------------------------------------------*
- CLASS lcl_limpiador DEFINITION FINAL.
- PUBLIC SECTION.
- TYPES:
- BEGIN OF ty_programa,
- programa TYPE progname,
- descripcion TYPE string,
- END OF ty_programa,
- ty_t_programas TYPE STANDARD TABLE OF ty_programa WITH EMPTY KEY.
- METHODS ejecutar
- IMPORTING it_programas TYPE ty_t_programas.
- PRIVATE SECTION.
- CONSTANTS:
- gc_estado_ok TYPE char1 VALUE 'S',
- gc_estado_error TYPE char1 VALUE 'E'.
- TYPES:
- BEGIN OF ty_paso,
- programa TYPE progname,
- descripcion TYPE string,
- estado TYPE char1,
- mensaje TYPE string,
- segundos TYPE p LENGTH 8 DECIMALS 2,
- detalle TYPE string_table,
- END OF ty_paso,
- ty_t_pasos TYPE STANDARD TABLE OF ty_paso WITH EMPTY KEY,
- ty_t_parametros TYPE STANDARD TABLE OF rsparams WITH EMPTY KEY.
- " Proceso de cada programa
- METHODS procesar_paso
- IMPORTING is_programa TYPE ty_programa
- RETURNING VALUE(rs_paso) TYPE ty_paso.
- METHODS existe_programa
- IMPORTING iv_programa TYPE progname
- RETURNING VALUE(rv_existe) TYPE abap_bool.
- " Autorizaciones (mismas comprobaciones que hace cada estándar)
- METHODS tiene_autorizacion
- IMPORTING iv_programa TYPE progname
- RETURNING VALUE(rv_ok) TYPE abap_bool.
- METHODS autorizacion_chip
- RETURNING VALUE(rv_ok) TYPE abap_bool.
- METHODS autorizacion_ui5
- RETURNING VALUE(rv_ok) TYPE abap_bool.
- METHODS autorizacion_gateway
- IMPORTING iv_clase TYPE seoclsname
- iv_vista TYPE viewname
- RETURNING VALUE(rv_ok) TYPE abap_bool.
- " Parámetros y lanzamiento
- METHODS obtener_parametros
- IMPORTING iv_programa TYPE progname
- RETURNING VALUE(rt_parametros) TYPE ty_t_parametros.
- METHODS parametro
- IMPORTING iv_nombre TYPE rsscr_name
- iv_valor TYPE clike
- RETURNING VALUE(rs_parametro) TYPE rsparams.
- METHODS lanzar_programa
- IMPORTING iv_programa TYPE progname
- it_parametros TYPE ty_t_parametros
- RETURNING VALUE(rt_detalle) TYPE string_table.
- METHODS leer_lista_memoria
- RETURNING VALUE(rt_lineas) TYPE string_table.
- METHODS evaluar_memoria_global
- CHANGING cs_paso TYPE ty_paso.
- " Lista de salida
- METHODS mostrar_lista
- IMPORTING it_pasos TYPE ty_t_pasos.
- METHODS escribir_cabecera.
- METHODS escribir_paso
- IMPORTING is_paso TYPE ty_paso.
- METHODS escribir_resumen
- IMPORTING it_pasos TYPE ty_t_pasos.
- ENDCLASS.
- CLASS lcl_limpiador IMPLEMENTATION.
- METHOD ejecutar.
- " Validación: al menos una opción marcada
- IF it_programas IS INITIAL.
- MESSAGE 'Marque al menos una opción' TYPE 'S' DISPLAY LIKE 'E'.
- RETURN.
- ENDIF.
- " Se ejecutan en el orden recibido y se recoge el resultado de cada uno
- DATA(lt_pasos) = VALUE ty_t_pasos( FOR ls_programa IN it_programas
- ( procesar_paso( ls_programa ) ) ).
- mostrar_lista( lt_pasos ).
- ENDMETHOD.
- METHOD procesar_paso.
- rs_paso = VALUE #( programa = is_programa-programa
- descripcion = is_programa-descripcion ).
- " 1. El programa debe existir en el sistema
- IF existe_programa( is_programa-programa ) = abap_false.
- rs_paso-estado = gc_estado_error.
- rs_paso-mensaje = 'El programa no existe en el sistema'.
- RETURN.
- ENDIF.
- " 2. Autorización previa: evita mensajes/popups del programa llamado
- IF tiene_autorizacion( is_programa-programa ) = abap_false.
- rs_paso-estado = gc_estado_error.
- rs_paso-mensaje = 'Sin autorización para ejecutar el programa'.
- RETURN.
- ENDIF.
- " 3. Limpieza de la memoria de retorno del GLOBAL
- IF is_programa-programa = gc_prog_global.
- FREE MEMORY ID gc_memid_glob.
- ENDIF.
- " 4. Ejecución silenciosa midiendo la duración
- GET RUN TIME FIELD DATA(lv_inicio).
- rs_paso-detalle = lanzar_programa(
- iv_programa = is_programa-programa
- it_parametros = obtener_parametros( is_programa-programa ) ).
- GET RUN TIME FIELD DATA(lv_fin).
- rs_paso-segundos = ( lv_fin - lv_inicio ) / 1000000.
- rs_paso-estado = gc_estado_ok.
- rs_paso-mensaje = 'Ejecutado correctamente'.
- " 5. El GLOBAL devuelve sus errores en memoria ABAP
- IF is_programa-programa = gc_prog_global.
- evaluar_memoria_global( CHANGING cs_paso = rs_paso ).
- ENDIF.
- ENDMETHOD.
- METHOD existe_programa.
- SELECT SINGLE name FROM trdir
- INTO @DATA(lv_nombre)
- WHERE name = @iv_programa.
- rv_existe = xsdbool( sy-subrc = 0 ).
- ENDMETHOD.
- METHOD tiene_autorizacion.
- rv_ok = SWITCH #( iv_programa
- WHEN gc_prog_bep THEN autorizacion_gateway( iv_clase = '/IWBEP/CL_COF_UTIL'
- iv_vista = '/IWBEP/I_MGW_CTC' )
- WHEN gc_prog_fnd THEN autorizacion_gateway( iv_clase = '/IWFND/CL_COF_UTIL'
- iv_vista = '/IWFND/I_MED_CTC' )
- WHEN gc_prog_ui5 THEN autorizacion_ui5( )
- ELSE autorizacion_chip( ) ).
- ENDMETHOD.
- METHOD autorizacion_chip.
- " Comprobación de los programas /UI2/*
- AUTHORITY-CHECK OBJECT '/UI2/CHIP'
- ID '/UI2/CHIP' FIELD 'X-SAP-UI2*'
- ID 'ACTVT' FIELD '06'.
- rv_ok = xsdbool( sy-subrc = 0 ).
- ENDMETHOD.
- METHOD autorizacion_ui5.
- " Comprobación de /UI5/APP_INDEX_CALCULATE (S_SUISUPRT o S_DEVELOP)
- AUTHORITY-CHECK OBJECT 'S_SUISUPRT'
- ID 'ACTVT' FIELD '02'
- ID 'SUI_AREA' FIELD 'UI5'.
- IF sy-subrc = 0.
- rv_ok = abap_true.
- RETURN.
- ENDIF.
- AUTHORITY-CHECK OBJECT 'S_DEVELOP'
- ID 'DEVCLASS' DUMMY
- ID 'OBJTYPE' DUMMY
- ID 'OBJNAME' DUMMY
- ID 'P_GROUP' DUMMY
- ID 'ACTVT' FIELD '02'.
- rv_ok = xsdbool( sy-subrc = 0 ).
- ENDMETHOD.
- METHOD autorizacion_gateway.
- " Llamada dinámica: evita dependencia de compilación con los
- " componentes de Gateway; cualquier excepción = sin autorización
- TRY.
- CALL METHOD (iv_clase)=>('AUTHORITY_CHECK_CONFIG')
- EXPORTING
- iv_db_name = iv_vista
- iv_read_only_access = abap_true.
- rv_ok = abap_true.
- CATCH cx_root.
- rv_ok = abap_false.
- ENDTRY.
- ENDMETHOD.
- METHOD obtener_parametros.
- CASE iv_programa.
- WHEN gc_prog_bep OR gc_prog_fnd.
- " Limpiar todos los modelos
- rt_parametros = VALUE #( ( parametro( iv_nombre = 'ALLMODEL' iv_valor = abap_true ) ) ).
- WHEN gc_prog_ui5.
- " Todos los repositorios, modo "caducados" (por defecto 24 h).
- " Se evita el modo 'recalcular todo' porque emite un aviso que
- " forzaría a mostrar la pantalla de selección
- rt_parametros = VALUE #( ( parametro( iv_nombre = 'P_ALL' iv_valor = abap_true ) )
- ( parametro( iv_nombre = 'P_ALL_A' iv_valor = abap_false ) )
- ( parametro( iv_nombre = 'P_ALL_D' iv_valor = abap_true ) ) ).
- WHEN gc_prog_global.
- " Modo ejecución
- rt_parametros = VALUE #( ( parametro( iv_nombre = 'GV_TEST' iv_valor = abap_false ) )
- ( parametro( iv_nombre = 'GV_EXE' iv_valor = abap_true ) ) ).
- WHEN gc_prog_client.
- " Para todos los usuarios
- rt_parametros = VALUE #( ( parametro( iv_nombre = 'GV_ALL' iv_valor = abap_true ) )
- ( parametro( iv_nombre = 'GV_USER' iv_valor = abap_false ) ) ).
- WHEN OTHERS.
- " /UI2/DELETE_CACHE_AFTER_IMP no tiene parámetros
- CLEAR rt_parametros.
- ENDCASE.
- ENDMETHOD.
- METHOD parametro.
- rs_parametro = VALUE #( selname = iv_nombre
- kind = 'P'
- sign = 'I'
- option = 'EQ'
- low = iv_valor ).
- ENDMETHOD.
- METHOD lanzar_programa.
- " Sin pantalla de selección; la lista se redirige a memoria
- SUBMIT (iv_programa)
- WITH SELECTION-TABLE it_parametros
- EXPORTING LIST TO MEMORY
- AND RETURN.
- " Se recupera la salida del estándar para mostrarla como detalle
- rt_detalle = leer_lista_memoria( ).
- ENDMETHOD.
- METHOD leer_lista_memoria.
- DATA lt_lista TYPE STANDARD TABLE OF abaplist.
- CALL FUNCTION 'LIST_FROM_MEMORY'
- TABLES
- listobject = lt_lista
- EXCEPTIONS
- not_found = 1
- OTHERS = 2.
- IF sy-subrc = 0 AND lt_lista IS NOT INITIAL.
- CALL FUNCTION 'LIST_TO_ASCI'
- EXPORTING
- convert_symb_and_icon_2_text = abap_true
- IMPORTING
- list_string_ascii = rt_lineas
- TABLES
- listobject = lt_lista
- EXCEPTIONS
- empty_list = 1
- list_index_invalid = 2
- OTHERS = 3.
- IF sy-subrc <> 0.
- CLEAR rt_lineas.
- ENDIF.
- ENDIF.
- " Se libera siempre la memoria de lista
- CALL FUNCTION 'LIST_FREE_MEMORY'.
- " Solo líneas con contenido, sin espacios sobrantes
- LOOP AT rt_lineas ASSIGNING FIELD-SYMBOL(<lv_linea>).
- <lv_linea> = condense( <lv_linea> ).
- ENDLOOP.
- DELETE rt_lineas WHERE table_line IS INITIAL.
- ENDMETHOD.
- METHOD evaluar_memoria_global.
- DATA lt_mensajes TYPE bapirettab.
- IMPORT msg = lt_mensajes FROM MEMORY ID gc_memid_glob.
- FREE MEMORY ID gc_memid_glob.
- IF line_exists( lt_mensajes[ type = 'E' ] ).
- cs_paso-estado = gc_estado_error.
- cs_paso-mensaje = 'Finalizado con errores'.
- " Se añaden los textos de error al detalle
- cs_paso-detalle = VALUE #( BASE cs_paso-detalle
- FOR ls_mensaje IN lt_mensajes
- WHERE ( type = 'E' )
- ( CONV string( ls_mensaje-message ) ) ).
- ENDIF.
- ENDMETHOD.
- METHOD mostrar_lista.
- escribir_cabecera( ).
- LOOP AT it_pasos INTO DATA(ls_paso).
- escribir_paso( ls_paso ).
- ENDLOOP.
- escribir_resumen( it_pasos ).
- ENDMETHOD.
- METHOD escribir_cabecera.
- FORMAT COLOR COL_HEADING INTENSIFIED ON.
- WRITE: / |Limpieza de cachés Fiori / Gateway - Sistema { sy-sysid } / Mandante { sy-mandt }|,
- AT sy-linsz space.
- FORMAT COLOR COL_HEADING INTENSIFIED OFF.
- WRITE: / |Usuario { sy-uname } - { sy-datum DATE = USER } { sy-uzeit TIME = USER }|,
- AT sy-linsz space.
- FORMAT RESET.
- ULINE.
- ENDMETHOD.
- METHOD escribir_paso.
- " Línea principal: semáforo, programa, descripción, resultado, duración
- DATA(lv_icono) = COND icon_d( WHEN is_paso-estado = gc_estado_ok
- THEN icon_led_green
- ELSE icon_led_red ).
- DATA(lv_color) = COND i( WHEN is_paso-estado = gc_estado_ok
- THEN col_positive
- ELSE col_negative ).
- SKIP.
- WRITE: / lv_icono AS ICON.
- FORMAT COLOR = lv_color INTENSIFIED ON.
- WRITE: (30) is_paso-programa,
- (60) is_paso-descripcion,
- (40) is_paso-mensaje,
- |{ is_paso-segundos } s|.
- FORMAT RESET.
- " Detalle: salida capturada del programa estándar
- IF is_paso-detalle IS INITIAL.
- WRITE: /6 '(sin salida del programa)' COLOR COL_NORMAL INTENSIFIED OFF.
- RETURN.
- ENDIF.
- LOOP AT is_paso-detalle INTO DATA(lv_detalle).
- WRITE: /6 lv_detalle COLOR COL_NORMAL INTENSIFIED OFF.
- ENDLOOP.
- ENDMETHOD.
- METHOD escribir_resumen.
- DATA(lv_total) = lines( it_pasos ).
- DATA(lv_errores) = REDUCE i( INIT lv_n = 0
- FOR ls_paso IN it_pasos
- WHERE ( estado = gc_estado_error )
- NEXT lv_n = lv_n + 1 ).
- SKIP.
- ULINE.
- IF lv_errores = 0.
- FORMAT COLOR COL_POSITIVE INTENSIFIED ON.
- ELSE.
- FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
- ENDIF.
- WRITE: / |Programas ejecutados: { lv_total } - Correctos: { lv_total - lv_errores } - Con error: { lv_errores }|,
- AT sy-linsz space.
- FORMAT RESET.
- ENDMETHOD.
- ENDCLASS.
- *----------------------------------------------------------------------*
- * Eventos
- *----------------------------------------------------------------------*
- INITIALIZATION.
- gv_tit1 = 'Gateway / SAPUI5'.
- gv_tbep = 'Caché de metadatos backend (/IWBEP/CACHE_CLEANUP)'.
- gv_tfnd = 'Caché de metadatos Gateway Hub (/IWFND/CACHE_CLEANUP)'.
- gv_tui5 = 'Recalcular índice de apps SAPUI5 (puede tardar)'.
- gv_tit2 = 'Fiori Launchpad (UI2)'.
- gv_tglo = 'Invalidar cachés globales (modo ejecución)'.
- gv_timp = 'Borrar caché UI2 de todos los mandantes (after import)'.
- gv_tcli = 'Invalidar cachés de cliente (todos los usuarios)'.
- START-OF-SELECTION.
- " Programas marcados, en el orden de ejecución recomendado
- DATA(gt_programas) = VALUE lcl_limpiador=>ty_t_programas(
- ( LINES OF COND #( WHEN p_bep = abap_true
- THEN VALUE #( ( programa = gc_prog_bep descripcion = gv_tbep ) ) ) )
- ( LINES OF COND #( WHEN p_fnd = abap_true
- THEN VALUE #( ( programa = gc_prog_fnd descripcion = gv_tfnd ) ) ) )
- ( LINES OF COND #( WHEN p_ui5 = abap_true
- THEN VALUE #( ( programa = gc_prog_ui5 descripcion = gv_tui5 ) ) ) )
- ( LINES OF COND #( WHEN p_global = abap_true
- THEN VALUE #( ( programa = gc_prog_global descripcion = gv_tglo ) ) ) )
- ( LINES OF COND #( WHEN p_imp = abap_true
- THEN VALUE #( ( programa = gc_prog_imp descripcion = gv_timp ) ) ) )
- ( LINES OF COND #( WHEN p_client = abap_true
- THEN VALUE #( ( programa = gc_prog_client descripcion = gv_tcli ) ) ) ) ).
- NEW lcl_limpiador( )->ejecutar( gt_programas ).